11.7 Other EBNF Definitions

SearchConditionStr

The syntax for this function shown in EBNF is:

SearchConditionStr
  ::= '"' Expression '"'

Figure 11.24 SearchConditionStr

SearchExprStrList

The syntax for this function shown in EBNF is:

SearchExprStrList
  ::= '[' '"' Expression '"' ( ',' '"' Expression '"' )* ']'

Figure 11.25 SearchExprStrList

ProjectedDocumentExprStr

The syntax for this function shown in EBNF is:

ProjectedDocumentExprStr
  ::= ProjectedSearchExprStrList | 'expr("' JSONDocumentExpression '")'

Figure 11.26 ProjectedDocumentExprStr

ProjectedSearchExprStrList

The syntax for this function shown in EBNF is:

ProjectedSearchExprStrList
  ::= '[' '"' Expression ( 'AS' Alias )? '"' ( ',' '"' Expression ( 'AS' Alias )? '"' )* ']'

Figure 11.27 ProjectedSearchExprStrList

SortExprStrList

The syntax for this function shown in EBNF is:

SortExprStrList
  ::= '[' '"' Expression ( 'ASC' | 'DESC' )? '"' ( ',' '"' Expression ( 'ASC' | 'DESC' )? '"' )* ']'

Figure 11.28 SortExprStrList

ExprOrLiteral

The syntax for this function shown in EBNF is:

ExprOrLiteral
  ::= 'expr("' Expression '")' | Literal

Figure 11.29 ExprOrLiteral

ExprOrLiterals

The syntax for this function shown in EBNF is:

ExprOrLiterals
  ::= ExprOrLiteral ( ',' ExprOrLiteral )*

Figure 11.30 ExprOrLiterals

ExprOrLiteralOrOperand

The syntax for this function shown in EBNF is:

ExprOrLiteralOrOperand
  ::= ExprOrLiteral

Figure 11.31 ExprOrLiteralOrOperand

PlaceholderValues

The syntax for this function shown in EBNF is:

PlaceholderValues
  ::= '{' PlaceholderName ':' ( ExprOrLiteral ) '}'

Figure 11.32 PlaceholderValues

PlaceholderName

The syntax for this function shown in EBNF is:

PlaceholderName
  ::= NamedPlaceholderNotQuestionmarkNotNumbered

Figure 11.33 PlaceholderName

DocPath

The syntax for this function shown in EBNF is:

DocPath
  ::= ( '[*]' | ( '[' Index ']' ) | '.*' | ( '.' StringLiteral ) | '**' )+

Figure 11.34 DocPath

Literal

The syntax for this function shown in EBNF is:

Literal
  ::= '"' StringLiteral '"' | Number | true | false | Document

Figure 11.35 Literal

Expression

Expression
  ::= Literal
   | DocPath
   | TableField
   | FunctionName '(' Expression ( ',' Expression )* ')'
   | ':' PlaceholderName
   | Expression Operator Expression
   | JSONExpression

Figure 11.36 Expression

Document

An API call expecting a JSON document allows the use of many data types to describe the document. Depending on the X DevAPI implementation and language any of the following data types can be used:

• String

• Native JSON

• JSON equivalent syntax

• DbDoc

• Generated Doc Classes

All implementations of X DevAPI allow expressing a document by the special DbDoc type and as a string.

The syntax for this function shown in EBNF is:

Document
  ::= JSONDocument | JSONEquivalentDocument | DbDoc | GeneratedDocumentClasses

Figure 11.37 Document

JSONExpression

The syntax for this function shown in EBNF is:

JSONExpression
  ::= JSONDocumentExpression | '[' Expression ( ',' Expression )* ']'

Figure 11.38 JSONExpression

JSONDocumentExpression

The syntax for this function shown in EBNF is:

JSONDocumentExpression
  ::= '{' StringLiteral ':' JSONExpression (',' StringLiteral ':' JSONExpression)* '}'

Figure 11.39 JSONDocumentExpression

FunctionName

The syntax for this function shown in EBNF is:

FunctionName
  ::= StringLiteral | StringLiteral '.' StringLiteral

Figure 11.40 FunctionName

DocumentOrJSON

The syntax for this function shown in EBNF is:

DocumentOrJSON
  ::= Document | 'expr("' JSONDocumentExpression '")'

Figure 11.41 DocumentOrJSON

TableField

The syntax for this function shown in EBNF is:

TableField
  ::= ( StringLiteral '.' )? ( StringLiteral '.' )? StringLiteral ( '@' DocPath )?

Figure 11.42 TableField

TableFields

The syntax for this function shown in EBNF is:

TableFields
  ::= ( '[' TableField ( ',' TableField )* ']' )

Figure 11.43 TableFields